The Genius of Edison/The Genius of Edison (Version 1.0)(Softkey Multimedia)(GOE744AE-CD)(1996).ISO/pc/data/shared.cst/00050_Script_Go Handlers

Text File | 1996-09-03 | 7KB | 291 lines

-- ---------------------------------------------------------------
-- Handler goWheel takes the user to the wheel.

on goWheel whichFrame
  stopSound

  if voidP(whichFrame) then
    go frame "startwheel" of movie "DSK.dir"
  else
    go frame whichFrame of movie "DSK.dir"
  end if

  initializeWheel
  setNonInventionSectionInfo("Wheel")
end

-- ---------------------------------------------------------------
-- Handler goTimeline takes the user to the TimeLine.

on goTimeline
  stopSound
  go movie "TL.dir"

  setNonInventionSectionInfo("Timeline")
end

-- ---------------------------------------------------------------
-- Handler goDataBase takes the user to the data section.

on goDataBase whichFrame
  stopSound

  if voidP(whichFrame) then
    go movie "DB.dir"
  else
    go frame whichFrame of movie "DB.dir"
  end if

  setNonInventionSectionInfo("Database")
end

-- ---------------------------------------------------------------
-- Handler goIndex takes the user to the Index.

on goIndex
  stopSound
  go movie "Index.dir"

  setNonInventionSectionInfo("Index")
end

-- ---------------------------------------------------------------
-- Handler goHelp takes the user to the Help section.

on goHelp
  stopSound
  go movie "help.dir"

  setNonInventionSectionInfo("Help")
end

-- ---------------------------------------------------------------
-- Handler goTour takes the user to the tour.

on goTour
  stopSound
  go frame "prog" of movie "InfoTou.dir"

  setNonInventionSectionInfo("Tour")
end

-- ---------------------------------------------------------------
-- Handler goIntro takes the user to the introduction.

on goIntro
  stopSound
  go movie "Intro.dir"

  setNonInventionSectionInfo("Intro")
end

-- ---------------------------------------------------------------
-- Handler goQuiz takes the user to the quiz.

on goQuiz
  stopSound
  go movie "QuizGam.dir"

  setNonInventionSectionInfo("Quiz")
end

-- ---------------------------------------------------------------
-- Handler doQuit quits the program.

on doQuit
  stopSound
  go movie "Credits.dir"

  --  setInInventionFlag(FALSE)
  --  setDEPFlag(FALSE)
end

-- ---------------------------------------------------------------
-- Handler goTomsTechnology takes the user to the tom's technology
-- section of the current invention.

on goTomsTechnology
  global inventionMovie

  watchCursor

  if (the movieName = inventionMovie) then
    goFrame "TT"
  else
    stopSound
    go frame "TT" of movie inventionMovie
  end if

  setInventionSubSectionInfo("Toms Technology", 0)

  normalCursor
end

-- ---------------------------------------------------------------
-- Handler goDailyEdisonian takes the user to the dailyEdisonian
-- section of the current invention.

on goDailyEdisonian
  global inventionMovie

  watchCursor

  if (the movieName = inventionMovie) then
    goFrame "DEP"
  else
    stopSound
    go frame "DEP" of movie inventionMovie
  end if

  setInventionSubSectionInfo("Daily Edisonian", 1)

  normalCursor
end

-- ---------------------------------------------------------------
-- Handler goTimeMarchesOn takes the user to the time marches on
-- section of the current invention.

on goTimeMarchesOn
  global inventionMovie

  watchCursor

  if (the movieName = inventionMovie) then
    goFrame "TMO"
  else
    stopSound
    go frame "TMO" of movie inventionMovie
  end if

  setInventionSubSectionInfo("Time Marches On", 0)

  normalCursor
end

-- ---------------------------------------------------------------
-- Handler goKinetoscope takes the user to the kinetoscope
-- section of the kinetoscope movie.

on goKinetoscope
  global inventionMovie

  watchCursor

  if (the movieName = inventionMovie) then
    goFrame "parlor"
  else
    stopSound
    go frame "parlor" of movie inventionMovie
  end if

  setInventionSubSectionInfo("Kinetoscope", 0)

  normalCursor
end

-- ---------------------------------------------------------------
-- Handler goKinetograph takes the user to the kinetograph
-- section of the kinetograph movie.

on goKinetograph
  global inventionMovie

  watchCursor

  if (the movieName = inventionMovie) then
    goFrame "reelstory"
  else
    stopSound
    go frame "reelstory" of movie inventionMovie
  end if

  setInventionSubSectionInfo("Kinetograph", 0)

  normalCursor
end

-- ---------------------------------------------------------------
-- Handler goMorse takes the user to the morse code game
-- section of the quadruplex movie.

on goMorse
  global inventionMovie

  watchCursor

  if (the movieName = "QDMorse.dir") then
    goFrame "start"
  else
    stopSound
    go frame "start" of movie "QDMorse.dir"
  end if

  setInventionSubSectionInfo("Morse", 0)

  normalCursor
end
-- ---------------------------------------------------------------
-- Handler setInInventions sets the global variable inInventionFlag to
-- the given value. This variable is used to determine if checkMenuRoll
-- should check if the user rolled over the local menu.

on setInInventionFlag val
  global inInventionFlag

  set inInventionFlag = val
end

-- -----------------------------------------------------------------------
-- Handler setDEPFlag sets the global variable depFlag to the given value.
-- This variabe is used to determine if checkMenuRoll should check for
-- rollover on the dep menu.

on setDEPFlag val
  global depFlag

  set depFlag = val
end

-- ---------------------------------------------------------------
-- Handler setNonInventionSectionInfo sets values that need to be set
-- when going to a section that is not part of an invention.

on setNonInventionSectionInfo whichSection
  setInInventionFlag(FALSE)
  setDEPFlag(FALSE)
  addCurrentSectionToBackList
  setCurrentSection(whichSection)
  setCurrentSubSection(EMPTY)
  setBackFlag(FALSE)
end

-- ---------------------------------------------------------------
-- Handler inDatabase

on inDatabase
  return (the movieName = "DB.dir")
end

-- ---------------------------------------------------------------
-- Handler inHelp

on inHelp
  return (the movieName = "Help.dir")
end

-- ---------------------------------------------------------------
-- Handler inTimeline

on inTimeLine
  return (the movieName = "TL.dir")
end


-- ---------------------------------------------------------------
-- Handler inMorse

on inMorse
  return (the movieName = "QDMorse.dir")
end